Create a Web Form. Then place the Labels, TextBoxes, Buttons, and DataGrid objects as seen in Figure 12.1 on the form with the properties set as in Table 12.3.

Table 12.3. Label, TextBox, and Button Control Property Settings

Object	Property	Setting
Label	Text	Last Name
TextBox	ID	txtLastName
Label	Text	First Name
TextBox	ID	txtFirstName
Button	ID	btnAdd
	Text	Add to DataTable
Button	ID	btnCreateXMLFile
	Text	Create XML File
DataGrid	ID	dgDataToWrite
HyperLink	ID	hplReturnToMain
	NavigateURL	wfrmMain.aspx

Add the following line to the code module of the form. Place it under the line that reads Web Form Designer Generated Code.

Dim mdtData As New DataTable()

Add the code in Listing 12.1 to the Load event of the page. If the data table has not been saved to the Session object, then you need to create it from scratch by first creating the data columns and then adding them to the data table. The DataTable object is then saved to the Session object with the name MyDataTable. If the Session object entry already exists, it is assigned back to the module variable mdtData. Last, the data table is bound to the DataGrid object by calling the BindTheGrid routine, which is described in the next step.

Listing 12.1 wfrmHowTo12_1.aspx.vb: Creating a DataTable Object from Scratch

Private Sub Page_Load(ByVal sender As System.Object, _
            ByVal e As System.EventArgs) Handles MyBase.Load

        'Put user code to initialize the page here
        If (Session("MyDataTable") Is Nothing) Then

            Dim dcFirstName As New DataColumn()

            dcFirstName.ColumnName = "FirstName"
            dcFirstName.Caption = "First Name"

            mdtData.Columns.Add(dcFirstName)

            Dim dcLastName As New DataColumn()

            dcLastName.ColumnName = "LastName"
            dcLastName.Caption = "Last Name"

            mdtData.Columns.Add(dcLastName)

            Session("MyDataTable") = mdtData

        Else
            mdtData = CType(Session("MyDataTable"), DataTable)
        End If

        BindTheGrid()

    End Sub

Create the routine BindTheGrid, shown in Listing 12.2, in the code module for the page.

Listing 12.2 wfrmHowTo12_1.aspx.vb: Binding the Data Table to the Data Grid

Sub BindTheGrid()

        dgDataToWrite.DataSource = mdtData
        dgDataToWrite.DataBind()

    End Sub

Add the code in Listing 12.3 to the Click event of the btnAdd button. This routine starts off by calling the NewRow method off the mdtData data table, thus creating a new DataRow object. The two columns in drNew are replaced with the values in txtLastName and txtFirstName. The new row is added to the data table, and the text boxes are cleared. Last, mdtData is rebound to the data grid by calling BindTheGrid.

Listing 12.3 wfrmHowTo12_1.aspx.vb: Adding Data to the Data Table and Then Rebinding the Data Grid

Private Sub btnAdd_Click(ByVal sender As System.Object, _
                           ByVal e As System.EventArgs) Handles btnAdd.Click

    Dim drNew As DataRow

    drNew = mdtData.NewRow()

    drNew.Item("LastName") = Me.txtLastName.Text
    drNew.Item("FirstName") = Me.txtFirstName.Text

    mdtData.Rows.Add(drNew)

    Me.txtLastName.Text = ""
    Me.txtFirstName.Text = ""

    BindTheGrid()

End Sub

Add the code in Listing 12.4 to the Click event of the btnCreateXMLFile button. The first task is to declare an instance of the XMLTextWriter. Then the XMLTextWriter creates and opens the file c:\Text.xml. Next, the XML document is created using the Write methods, including the writing of the individual rows of the DataTable object. Last, the data is flushed, and the XMLTextWriter is closed.

Listing 12.4 wfrmHowTo12_1.aspx.vb: Creating the XML Document

Private Sub btnCreateXMLFile_Click(ByVal sender As System.Object, _
                        ByVal e As System.EventArgs) Handles btnCreateXMLFile.Click

        Dim xtwMyData As System.Xml.XmlTextWriter = Nothing
        Dim intCurrRow As Integer
        Dim intNumRows As Integer

        xtwMyData = New System.Xml.XmlTextWriter("c:\Test.XML", Nothing)
        intNumRows = mdtData.Rows.Count - 1

        With xtwMyData
            .WriteStartDocument(False)
            .Formatting = System.Xml.Formatting.Indented
            .WriteDocType("Names", Nothing, Nothing, Nothing)
            .WriteComment("This file represents names list")
            .WriteStartElement("names")

            For intCurrRow = 0 To intNumRows
                '-- Start the current row
                .WriteStartElement("name", Nothing)

                '-- Write the fields
                .WriteAttributeString("FirstName", _
                            mdtData.Rows(intCurrRow).Item("FirstName"))
                .WriteAttributeString("LastName", _
                            mdtData.Rows(intCurrRow).Item("LastName"))

                '-- Ending the row
                .WriteEndElement()

            Next

            '-- Write the XML to file and close the writer
            .Flush()
            .Close()
        End With

    End Sub